options
{
//Case sensitivity is required for JSP/PHP keyword "switch".

	//Don't change Java unicode escapes.
	//JAVA_UNICODE_ESCAPE=true;
	//If Unicode input is used, fix Run.main() to use relevant another XXCharStream.
	UNICODE_INPUT=false;

	STATIC=true;
	//COMMON_TOKEN_ACTION=true; //=> void CommonTokenAction(Token t)

	CACHE_TOKENS=true; //=> for files / whole packets only - OK
	OPTIMIZE_TOKEN_MANAGER=true;

	//DEBUG_PARSER=true; -not useful
	//SANITY_CHECK default true

	OTHER_AMBIGUITY_CHECK=5;
	CHOICE_AMBIGUITY_CHECK=100000;
	FORCE_LA_CHECK=true; //maybe not recomended?

	//DEBUG_TOKEN_MANAGER=true;
}

PARSER_BEGIN(Parser)

package org.paneris.spindent;

public final class Parser {
}

PARSER_END(Parser)

<*> SPECIAL_TOKEN : {
	<#NO_WS:    ~[" ", "\t", "\f", "\n", "\r"] >
|	<#NO_QWS:   ~[" ", "\t", "\f", "\n", "\r", "'", "\""] > //No whitespace neither quotation mark/apostrophe
|	<#NO_TWS:   ~[" ", "\t", "\f", "\n", "\r", "<"] > //No whitespace neither "<" tag opener
| <#NO_TEQWS: ~[" ", "\t", "\f", "\n", "\r", ">", "'", "\""] > //No whitespace, ">" tag end, quotation/apostrophe
| <#NO_CR:    ~["\n", "\r"] >
| <#IS_WS:    ( [" ", "\t", "\f"] )+ >
| <#IS_CR:    ( ["\n", "\r"] )+ (["\n", "\r"] | <IS_WS>)* >
}

//List of all token manager states:
//DEFAULT, HTML_COMMENT, HTML_TAG, QUOTATION, APOSTROPHE, JAVASCRIPT, CODE, SINGLE_LINE_COMMENT, MULTILINE_COMMENT, PRE, SSI

//Fix if states are changed => all modes except SINGLE_LINE_COMMENT, MULTI_LINE_COMMENT, PRE, SSI:
<DEFAULT, HTML_COMMENT, HTML_TAG, QUOTATION, APOSTROPHE, JAVASCRIPT, CODE>
	SPECIAL_TOKEN: {	<CR: <IS_CR> > } //Empty new lines don't get indentation spaces added

//Fix if states are changed => all modes except SINGLE_LINE_COMMENT, MULTI_LINE_COMMENT, PRE, SSI, QUOTATION, APOSTROPHE:
<DEFAULT, HTML_COMMENT, HTML_TAG, JAVASCRIPT, CODE>
	SPECIAL_TOKEN: { <WS: <IS_WS> > }  //Multiple whitespaces inside text are easily replaced by 1 space

// DEFAULT state is html
// Token naming convention:
// H_xxx = HTML token XXX
// H_C_BEG = HTML token that starts CODE state
// C_H_END = CODE token that ends and returns to HTML state

<DEFAULT> SPECIAL_TOKEN [IGNORE_CASE]: {
	<H_HC_BEG: "<!--" > :HTML_COMMENT
| <H_BEGIN: "<table" | "<tr" | "<td" | "<select" > :HTML_TAG
| <H_CLOSE: "</table" | "</tr" | "</td" | "</select" > :HTML_TAG
| <H_TEXT: <NO_TWS> >
| <H_HT_BEG:    "<" > :HTML_TAG
| <H_CLOSE_TAG: "</" > :HTML_TAG //for lower/uppercase transformation
| <H_J_BEG: "<script"  ( ~[">"] )* ">" > :JAVASCRIPT
| <H_C_BEG: "<%" | "<?" > {Engine.pushPrevState(curLexState);} :CODE
| <H_P_BEG: "<pre" ( ~[">"] )* ">" > :PRE
| <H_SSI_BEG: "<!--" (<IS_WS>)* "#" > {Engine.pushPrevState(curLexState);} :SSI
}

<HTML_COMMENT> SPECIAL_TOKEN: {
	// <% and <? in HTML_COMMENT not supported - probably programmer error; <script> as well.
	<HC_H_END: "-->" > :DEFAULT
| <HC_CHAR: <NO_WS> >
}

<PRE> SPECIAL_TOKEN: {
	<P_CHAR: ~[] >
| <P_H_END: "</pre" > :DEFAULT
| <P_C_BEG: "<%" | "<?" > {Engine.pushPrevState(curLexState);} :CODE
| <P_SSI_BEG: "<!--" (<IS_WS>)* "#" > {Engine.pushPrevState(curLexState);} :SSI
}

<SSI> SPECIAL_TOKEN: {
	<SSI_CHAR: ~[] >
| <SSI_X_END: "-->" > {SwitchTo(Engine.popPrevState());}
}

<HTML_TAG> SPECIAL_TOKEN: {
	// <XML-tag can be on multiple lines>
  <HT_QUOTE: "\"" > {Engine.pushPrevState(curLexState);} :QUOTATION
| <HT_APOST: "'"  > {Engine.pushPrevState(curLexState);} :APOSTROPHE
| <HT_H_SINGLE_END: "/>" > :DEFAULT
| <HT_H_END: ">" > :DEFAULT
| <HT_C_BEG: "<%" | "<?" > {Engine.pushPrevState(curLexState);} :CODE
| <HT_CHAR: <NO_TEQWS> >
| <HT_SSI_BEG: "<!--" (<IS_WS>)* "#" > {Engine.pushPrevState(curLexState);} :SSI
}

//Multiline QUOTATION/APOSTROPHE don't work for Java, thus not supported. So successive lines will be indented.
//Should there be a need, exempt <CR> from QUOTATION/APOSTROPHE states and manage Engine.indent(tok) and unindentSpaces.
<QUOTATION> SPECIAL_TOKEN: {
	<Q_X_END: "\"" > {SwitchTo(Engine.popPrevState());}
| <Q_C_BEG: "<%" | "<?" > {Engine.pushPrevState(curLexState);} :CODE
| <Q_CHAR: ~["\""] | "\\\"" >
| <Q_SSI_BEG: "<!--" (<IS_WS>)* "#" > {Engine.pushPrevState(curLexState);} :SSI
}

<APOSTROPHE> SPECIAL_TOKEN: {
	<A_X_END: "'" > {SwitchTo(Engine.popPrevState());}
| <A_C_BEG: "<%" | "<?" > {Engine.pushPrevState(curLexState);} :CODE
| <A_CHAR: ~["'"] | "\\'" >
| <A_SSI_BEG: "<!--" (<IS_WS>)* "#" > {Engine.pushPrevState(curLexState);} :SSI
}

<JAVASCRIPT> SPECIAL_TOKEN [IGNORE_CASE]: {
  <J_Q_BEG: "\"" > {Engine.pushPrevState(curLexState);} :QUOTATION
| <J_A_BEG: "'" > {Engine.pushPrevState(curLexState);} :APOSTROPHE
| <J_BEGIN_BRACE:  "{" >
| <J_CLOSE_BRACE: "}" >
| <J_BEGIN_PAREN: "(" >
| <J_CLOSE_PAREN: ")" >
| <J_C_BEG: "<%" | "<?" > {Engine.pushPrevState(curLexState);} :CODE
| <J_CHAR: <NO_QWS> >
| <J_SC_BEG: "//"> {Engine.pushPrevState(curLexState);} :SINGLE_LINE_COMMENT
| <J_M_BEG: "/*"> {Engine.pushPrevState(curLexState);} :MULTI_LINE_COMMENT
| <J_H_END: "</script" ( ~[">"] )* ">" > :DEFAULT //Enclosing ">" can be left for DEFAULT if DEFAULT is fine with that.
| <J_SSI_BEG: "<!--" (<IS_WS>)* "#" > {Engine.pushPrevState(curLexState);} :SSI
}

<JAVASCRIPT> SPECIAL_TOKEN [IGNORE_CASE]: {
	<J_BEGIN_VBSCRIPT: "IF" | "FOR" | "WHILE" | "SUB" >
| <J_CLOSE_VBSCRIPT: ("END" (<IS_WS> | <IS_CR>)+ "IF") | "NEXT" | "WEND" | ("END" (<IS_WS> | <IS_CR>)+ "SUB") >
}

<CODE> SPECIAL_TOKEN: { 
	<C_Q_BEG:      "\"" > {Engine.pushPrevState(curLexState);} :QUOTATION
| <C_A_BEG:       "'" > {Engine.pushPrevState(curLexState);} :APOSTROPHE
| <C_BEGIN_BRACE:  "{" >
| <C_CLOSE_BRACE: "}" >
| <C_BEGIN_PAREN: "(" >
| <C_CLOSE_PAREN: ")" >
| <C_CASE: "case" >
| <C_CHAR:        <NO_QWS> >
| <C_X_END:       "%>" | "?>" > {SwitchTo(Engine.popPrevState());}
| <C_SC_BEG:      "//" > {Engine.pushPrevState(curLexState);} :SINGLE_LINE_COMMENT //Ending new line characters are parsed separately
| <C_M_BEG:      "/*" > {Engine.pushPrevState(curLexState);} :MULTI_LINE_COMMENT
}

<CODE> SPECIAL_TOKEN [IGNORE_CASE]: {
	<C_BEGIN_VBSCRIPT: "IF" | "FOR" | "WHILE" | "SUB" >
| <C_CLOSE_VBSCRIPT: ("END" (<IS_WS> | <IS_CR>)+ "IF") | "NEXT" | "WEND" | ("END" (<IS_WS> | <IS_CR>)+ "SUB") >
}

<SINGLE_LINE_COMMENT> SPECIAL_TOKEN: {
	<S_WS:     <IS_WS> >
| <S_X_END:  <IS_CR> > {SwitchTo(Engine.popPrevState());}
//Back through CODE to HTML only; not back through JAVASCRIPT:
| <S_XX_END: "%>" | "?>" > {
	int prevState;
	do { prevState=Engine.popPrevState(); }
	while(prevState!=CODE);
	SwitchTo( Engine.popPrevState()); //=>DEFAULT/ PRE/ HTML_TAG/ QUOTATION/ APOSTROPHE
	//Plus: unindent in Engine.indent(tok) only if Engine.codeIndent=true.
}
| <S_CHAR:   <NO_WS> >
}

<MULTI_LINE_COMMENT> SPECIAL_TOKEN: {
//Escape to CODE by %> leaves unpaired JSP comment and thus it is not supported.
	<M_WS:   <IS_WS> >
| <M_CR:   <IS_CR> >
| <M_CHAR: <NO_WS> >
| <M_X_END: "*/" > {SwitchTo(Engine.popPrevState());}
}

String File() /*throws...*/: {
	Token t;
} {
	try {
		t=<EOF>
		{ return Engine.toStringAll(t); }
	}
	catch(TransparentFault ex) { throw ex.source; }
}